app-admin/logstash-bin/logstash-bin-5.3.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit user
   7
   8 MY_PN="${PN%-bin}"
   9 MY_P="${MY_PN}-${PV}"
  10
  11 DESCRIPTION="Tool for managing events and logs"
  12 HOMEPAGE="https://www.elastic.co/products/logstash"
  13 SRC_URI="https://artifacts.elastic.co/downloads/${MY_PN}/${MY_P}.zip"
  14
  15 # source: LICENSE.txt and NOTICE.txt
  16 LICENSE="Apache-2.0 MIT"
  17 SLOT="0"
  18 KEYWORDS="~amd64"
  19
  20 RESTRICT="strip"
  21 QA_PREBUILT="opt/logstash/vendor/jruby/lib/jni/*/libjffi*.so"
  22
  23 RDEPEND="virtual/jre:1.8"
  24
  25 S="${WORKDIR}/${MY_P}"
  26
  27 pkg_setup() {
  28         enewgroup ${MY_PN}
  29         enewuser ${MY_PN} -1 -1 /var/lib/${MY_PN} ${MY_PN}
  30 }
  31
  32 src_install() {
  33         keepdir /etc/"${MY_PN}"/{conf.d,patterns,plugins}
  34         keepdir "/var/log/${MY_PN}"
  35
  36         insinto "/usr/share/${MY_PN}"
  37         newins "${FILESDIR}/agent.conf.sample" agent.conf
  38
  39         insinto "/opt/${MY_PN}"
  40         doins -r .
  41         fperms 0755 "/opt/${MY_PN}/bin/${MY_PN}" "/opt/${MY_PN}/vendor/jruby/bin/jruby" "/opt/${MY_PN}/bin/logstash-plugin"
  42
  43         insinto /etc/logrotate.d
  44         newins "${FILESDIR}/${MY_PN}.logrotate" "${MY_PN}"
  45
  46         newconfd "${FILESDIR}/${MY_PN}.confd" "${MY_PN}"
  47         newinitd "${FILESDIR}/${MY_PN}.initd" "${MY_PN}"
  48 }
  49
  50 pkg_postinst() {
  51         ewarn "The default user changed from root to ${MY_PN}. If you wish to run as root (for"
  52         ewarn "example to read local logs), be sure to change LS_USER and LS_GROUP in"
  53         ewarn "${EROOT%/}/etc/conf.d/${MY_PN}"
  54         einfo
  55         einfo "Installing plugins: (bug #601294)"
  56         einfo "DEBUG=1 JARS_SKIP='true' bin/logstash-plugin install logstash-output-gelf"
  57 }