app-admin/fam/fam-2.7.0_p17_p2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools eutils flag-o-matic ltprune multilib-minimal
   6
   7 FAM_PV="${PV/_p*/}"
   8 DEBIAN_PATCH="${PV#*_p}"
   9 DEBIAN_PATCH="${DEBIAN_PATCH/_p/.}"
  10 DESCRIPTION="FAM, the File Alteration Monitor"
  11 HOMEPAGE="http://oss.sgi.com/projects/fam/"
  12 SRC_URI="
  13         ftp://oss.sgi.com/projects/fam/download/stable/${PN}-${FAM_PV}.tar.gz
  14         mirror://debian/pool/main/f/${PN}/${PN}_${FAM_PV}-${DEBIAN_PATCH}.diff.gz
  15 "
  16
  17 LICENSE="GPL-2 LGPL-2.1"
  18 SLOT="0"
  19 KEYWORDS="~alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86"
  20 IUSE="static-libs"
  21
  22 DEPEND="
  23         !app-admin/gamin
  24         net-libs/libtirpc
  25         net-nds/rpcbind
  26 "
  27 RDEPEND="
  28         ${DEPEND}
  29 "
  30 DOCS=( AUTHORS ChangeLog INSTALL NEWS TODO README )
  31 S=${WORKDIR}/${PN}-${FAM_PV}
  32
  33 src_prepare() {
  34         eapply "${WORKDIR}"/${PN}_${FAM_PV}-${DEBIAN_PATCH}.diff
  35         edos2unix debian/patches/10_debianbug375967.patch
  36         eapply "${FILESDIR}"/${PN}-${FAM_PV}-patch-header.patch
  37
  38         eapply debian/patches/*patch
  39
  40         eapply "${FILESDIR}"/${PN}-${FAM_PV}-AM_CONFIG_HEADER.patch
  41         eapply "${FILESDIR}"/${PN}-${FAM_PV}-out-of-tree.patch
  42         eapply "${FILESDIR}"/${PN}-${FAM_PV}-sysmacros.patch #580702
  43
  44         eapply_user
  45
  46         eautoreconf
  47 }
  48
  49 multilib_src_configure() {
  50         tc-export PKG_CONFIG
  51         append-cppflags $(${PKG_CONFIG} --cflags libtirpc)
  52         append-libs $(${PKG_CONFIG} --libs libtirpc)
  53         ECONF_SOURCE=${S} econf $(use_enable static-libs static)
  54
  55         # These are thrown away later
  56         if ! multilib_is_native_abi ; then
  57                 sed -i -e 's/src conf man//' Makefile || die
  58         fi
  59 }
  60
  61 multilib_src_install_all() {
  62         prune_libtool_files
  63         einstalldocs
  64
  65         sed -i "${D}"/etc/fam.conf \
  66                 -e "s:local_only = false:local_only = true:g" \
  67                 || die "sed fam.conf"
  68
  69         doinitd "${FILESDIR}/famd"
  70 }