app-admin/calamares/calamares-3.2.12.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 KDE_TEST="true"
   7 PYTHON_COMPAT=( python3_6 )
   8 inherit kde5 python-r1
   9
  10 DESCRIPTION="Distribution-independent installer framework"
  11 HOMEPAGE="https://calamares.io"
  12 if [[ ${KDE_BUILD_TYPE} == live ]] ; then
  13         EGIT_REPO_URI="https://github.com/${PN}/${PN}"
  14 else
  15         SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
  16         KEYWORDS="~amd64"
  17 fi
  18
  19 LICENSE="GPL-3"
  20 IUSE="+networkmanager pythonqt +upower"
  21
  22 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  23
  24 BDEPEND="
  25         $(add_qt_dep linguist-tools)
  26 "
  27 COMMON_DEPEND="${PYTHON_DEPS}
  28         $(add_frameworks_dep kconfig)
  29         $(add_frameworks_dep kcoreaddons)
  30         $(add_frameworks_dep kcrash)
  31         $(add_frameworks_dep kpackage)
  32         $(add_frameworks_dep kparts)
  33         $(add_frameworks_dep kservice)
  34         $(add_qt_dep qtconcurrent)
  35         $(add_qt_dep qtdbus)
  36         $(add_qt_dep qtdeclarative)
  37         $(add_qt_dep qtgui)
  38         $(add_qt_dep qtnetwork)
  39         $(add_qt_dep qtsvg)
  40         $(add_qt_dep qtwebengine 'widgets')
  41         $(add_qt_dep qtwidgets)
  42         $(add_qt_dep qtxml)
  43         dev-cpp/yaml-cpp:=
  44         >=dev-libs/boost-1.55:=[python,${PYTHON_USEDEP}]
  45         dev-libs/libpwquality[${PYTHON_USEDEP}]
  46         sys-apps/dbus
  47         sys-apps/dmidecode
  48         sys-auth/polkit-qt[qt5(+)]
  49         >=sys-libs/kpmcore-4.0.0:5=
  50         pythonqt? ( >=dev-python/PythonQt-3.1:=[${PYTHON_USEDEP}] )
  51 "
  52 DEPEND="${COMMON_DEPEND}
  53         test? ( $(add_qt_dep qttest) )
  54 "
  55 RDEPEND="${COMMON_DEPEND}
  56         app-admin/sudo
  57         dev-libs/libatasmart
  58         net-misc/rsync
  59         || ( sys-boot/grub:2 sys-boot/systemd-boot )
  60         sys-boot/os-prober
  61         sys-fs/squashfs-tools
  62         sys-libs/timezone-data
  63         virtual/udev
  64         networkmanager? ( net-misc/networkmanager )
  65         upower? ( sys-power/upower )
  66 "
  67
  68 src_prepare() {
  69         cmake-utils_src_prepare
  70         python_setup
  71         export PYTHON_INCLUDE_DIRS="$(python_get_includedir)" \
  72                PYTHON_INCLUDE_PATH="$(python_get_library_path)"\
  73                PYTHON_CFLAGS="$(python_get_CFLAGS)"\
  74                PYTHON_LIBS="$(python_get_LIBS)"
  75
  76         sed -i -e 's:pkexec /usr/bin/calamares:calamares-pkexec:' \
  77                 calamares.desktop || die
  78         sed -i -e 's:Icon=calamares:Icon=drive-harddisk:' \
  79                 calamares.desktop || die
  80 }
  81
  82 src_configure() {
  83         local mycmakeargs=(
  84                 -DWEBVIEW_FORCE_WEBKIT=OFF
  85                 -DCMAKE_DISABLE_FIND_PACKAGE_LIBPARTED=ON
  86                 -DWITH_PYTHONQT=$(usex pythonqt)
  87         )
  88
  89         kde5_src_configure
  90 }
  91
  92 src_install() {
  93         kde5_src_install
  94         dobin "${FILESDIR}"/calamares-pkexec
  95 }