app-admin/ansible/ansible-9999.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 python3_{5,6} )
   7
   8 inherit distutils-r1 git-r3 eutils
   9
  10 DESCRIPTION="Model-driven deployment, config management, and command execution framework"
  11 HOMEPAGE="https://ansible.com/"
  12 EGIT_REPO_URI="https://github.com/ansible/ansible.git"
  13 EGIT_BRANCH="devel"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS=""
  18 IUSE="doc test"
  19
  20 RDEPEND="
  21         dev-python/paramiko[${PYTHON_USEDEP}]
  22         dev-python/jinja[${PYTHON_USEDEP}]
  23         dev-python/pyyaml[${PYTHON_USEDEP}]
  24         dev-python/setuptools[${PYTHON_USEDEP}]
  25         dev-python/cryptography[${PYTHON_USEDEP}]
  26         dev-python/httplib2[${PYTHON_USEDEP}]
  27         dev-python/six[${PYTHON_USEDEP}]
  28         dev-python/netaddr[${PYTHON_USEDEP}]
  29         net-misc/sshpass
  30         virtual/ssh
  31 "
  32 DEPEND="
  33         dev-python/setuptools[${PYTHON_USEDEP}]
  34         >=dev-python/packaging-16.6[${PYTHON_USEDEP}]
  35         doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
  36         test? (
  37                 ${RDEPEND}
  38                 dev-python/nose[${PYTHON_USEDEP}]
  39                 >=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
  40                 dev-python/passlib[${PYTHON_USEDEP}]
  41                 dev-python/coverage[${PYTHON_USEDEP}]
  42                 dev-python/unittest2[${PYTHON_USEDEP}]
  43                 dev-vcs/git
  44         )"
  45
  46 python_compile_all() {
  47         if use doc; then
  48                 cd docs/docsite || die
  49                 export CPUS=4
  50                 emake -f Makefile.sphinx html
  51         fi
  52 }
  53
  54 python_prepare_all() {
  55         rm -fv MANIFEST.in || die
  56         distutils-r1_python_prepare_all
  57 }
  58
  59 python_test() {
  60         nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
  61 }
  62
  63 python_install_all() {
  64         use doc && local HTML_DOCS=( docs/docsite/_build/html/. )
  65         distutils-r1_python_install_all
  66
  67         doman docs/man/man1/*.1
  68         dodoc -r examples
  69 }