app-admin/ansible/ansible-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7
   8 inherit distutils-r1 git-r3 eutils
   9
  10 DESCRIPTION="Model-driven deployment, config management, and command execution framework"
  11 HOMEPAGE="https://ansible.com/"
  12 EGIT_REPO_URI="https://github.com/ansible/ansible.git"
  13 EGIT_BRANCH="devel"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS=""
  18 IUSE="doc test"
  19 RESTRICT="test"
  20
  21 RDEPEND="
  22         dev-python/paramiko[${PYTHON_USEDEP}]
  23         dev-python/jinja[${PYTHON_USEDEP}]
  24         dev-python/pyyaml[${PYTHON_USEDEP}]
  25         dev-python/setuptools[${PYTHON_USEDEP}]
  26         dev-python/cryptography[${PYTHON_USEDEP}]
  27         dev-python/httplib2[${PYTHON_USEDEP}]
  28         dev-python/six[${PYTHON_USEDEP}]
  29         dev-python/netaddr[${PYTHON_USEDEP}]
  30         dev-python/pexpect[${PYTHON_USEDEP}]
  31         net-misc/sshpass
  32         virtual/ssh
  33 "
  34 DEPEND="
  35         dev-python/setuptools[${PYTHON_USEDEP}]
  36         >=dev-python/packaging-16.6[${PYTHON_USEDEP}]
  37         doc? (
  38                 dev-python/sphinx[${PYTHON_USEDEP}]
  39                 dev-python/sphinx-notfound-page[${PYTHON_USEDEP}]
  40                 >=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
  41         )
  42         test? (
  43                 ${RDEPEND}
  44                 dev-python/nose[${PYTHON_USEDEP}]
  45                 >=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
  46                 dev-python/passlib[${PYTHON_USEDEP}]
  47                 dev-python/coverage[${PYTHON_USEDEP}]
  48                 dev-python/unittest2[${PYTHON_USEDEP}]
  49                 dev-vcs/git
  50         )"
  51
  52 python_compile_all() {
  53         if use doc; then
  54                 cd docs/docsite || die
  55                 export CPUS=4
  56                 emake -f Makefile.sphinx html
  57         fi
  58 }
  59
  60 python_test() {
  61         nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
  62 }
  63
  64 python_install_all() {
  65         use doc && local HTML_DOCS=( docs/docsite/_build/html/. )
  66         distutils-r1_python_install_all
  67
  68         dodoc -r examples
  69 }