app-admin/ansible/ansible-1.9.4.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python2_7 )
   8
   9 inherit distutils-r1 eutils readme.gentoo
  10
  11 DESCRIPTION="Radically simple deployment, model-driven configuration management, and command execution framework"
  12 HOMEPAGE="http://ansible.com/"
  13 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86 ~x64-macos"
  18 IUSE="test"
  19
  20 RDEPEND="
  21         dev-python/httplib2[${PYTHON_USEDEP}]
  22         dev-python/jinja[${PYTHON_USEDEP}]
  23         dev-python/keyczar[${PYTHON_USEDEP}]
  24         >=dev-python/pycrypto-2.6[${PYTHON_USEDEP}]
  25         dev-python/pyyaml[${PYTHON_USEDEP}]
  26         dev-python/setuptools[${PYTHON_USEDEP}]
  27         net-misc/sshpass
  28         virtual/ssh
  29 "
  30 DEPEND="
  31         dev-python/setuptools[${PYTHON_USEDEP}]
  32         test? (
  33                 ${RDEPEND}
  34                 dev-python/mock[${PYTHON_USEDEP}]
  35                 dev-python/nose[${PYTHON_USEDEP}]
  36                 dev-python/passlib[${PYTHON_USEDEP}]
  37                 dev-vcs/git
  38         )"
  39
  40 # not included in release tarball
  41 RESTRICT="test"
  42
  43 python_test() {
  44         nosetests -d -w test/units -v --with-coverage --cover-package=ansible --cover-branches || die
  45 }
  46
  47 python_install_all() {
  48         EXAMPLES=( examples )
  49         distutils-r1_python_install_all
  50
  51         doman docs/man/man1/*.1
  52
  53         newenvd "${FILESDIR}"/${PN}.env 95ansible
  54 }
  55
  56 src_install() {
  57         distutils-r1_src_install
  58         readme.gentoo_create_doc
  59 }
  60
  61 pkg_postinst() {
  62         optfeature "Alternative ssh transport" dev-python/paramiko
  63 }