app-accessibility/accerciser/accerciser-3.22.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python{3_4,3_5} )
   6 PYTHON_REQ_USE="xml"
   7
   8 inherit gnome2 python-r1
   9
  10 DESCRIPTION="Interactive Python accessibility explorer"
  11 HOMEPAGE="https://wiki.gnome.org/Apps/Accerciser"
  12
  13 LICENSE="BSD CC-BY-SA-3.0"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~x86"
  16 IUSE=""
  17
  18 RDEPEND="
  19         >=app-accessibility/at-spi2-core-2.5.2:2
  20         >=dev-python/pygobject-2.90.3:3[${PYTHON_USEDEP}]
  21         >=x11-libs/gtk+-3.1.13:3[introspection]
  22
  23         dev-libs/atk[introspection]
  24         >=dev-libs/glib-2.28:2
  25         dev-libs/gobject-introspection:=
  26         >=dev-python/ipython-0.11[${PYTHON_USEDEP}]
  27         >=dev-python/pyatspi-2.1.5[${PYTHON_USEDEP}]
  28         dev-python/pycairo[${PYTHON_USEDEP}]
  29         x11-libs/gdk-pixbuf[introspection]
  30         x11-libs/libwnck:3[introspection]
  31         x11-libs/pango[introspection]
  32         ${PYTHON_DEPS}
  33 "
  34 DEPEND="${RDEPEND}
  35         app-text/yelp-tools
  36         >=dev-util/intltool-0.35
  37         sys-devel/gettext
  38         virtual/pkgconfig
  39 "
  40
  41 src_prepare() {
  42         gnome2_src_prepare
  43
  44         # Leave shebang alone
  45         sed 's:@PYTHON@:/usr/bin/python:' -i src/accerciser.in || die
  46
  47         python_copy_sources
  48 }
  49
  50 src_configure() {
  51         python_foreach_impl run_in_build_dir gnome2_src_configure
  52 }
  53
  54 src_compile() {
  55         python_foreach_impl run_in_build_dir gnome2_src_compile
  56 }
  57
  58 src_install() {
  59         installing() {
  60                 gnome2_src_install
  61                 python_doscript src/accerciser
  62         }
  63         python_foreach_impl run_in_build_dir installing
  64 }