Crypt/Monkeysphere/MSVA.pm

   1 # Monkeysphere Validation Agent, Perl version
   2 # Copyright © 2010 Daniel Kahn Gillmor <dkg@fifthhorseman.net>,
   3 #                  Jameson Rollins <jrollins@finestructure.net>
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 { package Crypt::Monkeysphere::MSVA;
  19
  20   use strict;
  21   use warnings;
  22   use vars qw($VERSION);
  23
  24   use parent qw(HTTP::Server::Simple::CGI);
  25   require Crypt::X509;
  26   use Regexp::Common qw /net/;
  27   use Convert::ASN1;
  28   use MIME::Base64;
  29   use IO::Socket;
  30   use IO::File;
  31   use Socket;
  32   use File::Spec;
  33   use File::HomeDir;
  34   use Config::General;
  35   use Crypt::Monkeysphere::MSVA::MarginalUI;
  36   use Crypt::Monkeysphere::MSVA::Logger;
  37   use Crypt::Monkeysphere::MSVA::Monitor;
  38
  39   use JSON;
  40   use POSIX qw(strftime);
  41   # we need the version of GnuPG::Interface that knows about pubkey_data, etc:
  42   use GnuPG::Interface 0.42.02;
  43
  44   $VERSION = '0.8';
  45
  46   my $gnupg = GnuPG::Interface::->new();
  47   $gnupg->options->quiet(1);
  48   $gnupg->options->batch(1);
  49
  50   my %dispatch = (
  51                   '/' => { handler => \&noop,
  52                            methods => { 'GET' => 1 },
  53                          },
  54                   '/reviewcert' => { handler => \&reviewcert,
  55                                      methods => { 'POST' => 1 },
  56                                    },
  57                   '/extracerts' => { handler => \&extracerts,
  58                                      methods => { 'POST' => 1 },
  59                                    },
  60                  );
  61
  62   my $default_keyserver = 'hkp://pool.sks-keyservers.net';
  63   my $default_keyserver_policy = 'unlessvalid';
  64
  65   my $logger = Crypt::Monkeysphere::MSVA::Logger::->new($ENV{MSVA_LOG_LEVEL});
  66   sub logger {
  67     return $logger;
  68   }
  69
  70   my $rsa_decoder = Convert::ASN1::->new();
  71   $rsa_decoder->prepare(q<
  72
  73    SEQUENCE {
  74         modulus INTEGER,
  75         exponent INTEGER
  76    }
  77           >);
  78
  79   sub net_server {
  80     return 'Net::Server::MSVA';
  81   };
  82
  83   sub msvalog {
  84     return $logger->log(@_);
  85   };
  86
  87   sub new {
  88     my $class = shift;
  89
  90     my $port = 0;
  91     if (exists $ENV{MSVA_PORT} and $ENV{MSVA_PORT} ne '') {
  92       msvalog('debug', "MSVA_PORT set to %s\n", $ENV{MSVA_PORT});
  93       $port = $ENV{MSVA_PORT} + 0;
  94       die sprintf("not a reasonable port %d", $port) if (($port >= 65536) || $port <= 0);
  95     }
  96     # start the server on requested port
  97     my $self = $class->SUPER::new($port);
  98     if (! exists $ENV{MSVA_PORT}) {
  99       # we can't pass port 0 to the constructor because it evaluates
 100       # to false, so HTTP::Server::Simple just uses its internal
 101       # default of 8080.  But if we want to select an arbitrary open
 102       # port, we *can* set it here.
 103       $self->port(0);
 104     }
 105
 106     $self->{allowed_uids} = {};
 107     if (exists $ENV{MSVA_ALLOWED_USERS} and $ENV{MSVA_ALLOWED_USERS} ne '') {
 108       msvalog('verbose', "MSVA_ALLOWED_USERS environment variable is set.\nLimiting access to specified users.\n");
 109       foreach my $user (split(/ +/, $ENV{MSVA_ALLOWED_USERS})) {
 110         my ($name, $passwd, $uid);
 111         if ($user =~ /^[0-9]+$/) {
 112           $uid = $user + 0; # force to integer
 113         } else {
 114           ($name,$passwd,$uid) = getpwnam($user);
 115         }
 116         if (defined $uid) {
 117           msvalog('verbose', "Allowing access from user ID %d\n", $uid);
 118           $self->{allowed_uids}->{$uid} = $user;
 119         } else {
 120           msvalog('error', "Could not find user '%d'; not allowing\n", $user);
 121         }
 122       }
 123     } else {
 124       # default is to allow access only to the current user
 125       $self->{allowed_uids}->{POSIX::getuid()} = 'self';
 126     }
 127
 128     bless ($self, $class);
 129     return $self;
 130   }
 131
 132   sub noop {
 133     my $self = shift;
 134     my $cgi = shift;
 135     return '200 OK', { available => JSON::true,
 136                        protoversion => 1,
 137                      };
 138   }
 139
 140   sub opensshpubkey2key {
 141     my $data = shift;
 142     # FIXME: do we care that the label matches the type of key?
 143     my ($label, $prop) = split(/ +/, $data);
 144
 145     my $out = parse_rfc4716body($prop);
 146
 147     return $out;
 148   }
 149
 150   sub rfc47162key {
 151     my $data = shift;
 152
 153     my @goodlines;
 154     my $continuation = '';
 155     my $state = 'outside';
 156     foreach my $line (split(/\n/, $data)) {
 157       last if ($state eq 'body' && $line eq '---- END SSH2 PUBLIC KEY ----');
 158       if ($state eq 'outside' && $line eq '---- BEGIN SSH2 PUBLIC KEY ----') {
 159         $state = 'header';
 160         next;
 161       }
 162       if ($state eq 'header') {
 163         $line = $continuation.$line;
 164         $continuation = '';
 165         if ($line =~ /^(.*)\\$/) {
 166           $continuation = $1;
 167           next;
 168         }
 169         if (! ($line =~ /:/)) {
 170           $state = 'body';
 171         }
 172       }
 173       push(@goodlines, $line) if ($state eq 'body');
 174     }
 175
 176     msvalog('debug', "Found %d lines of RFC4716 body:\n%s\n",
 177             scalar(@goodlines),
 178             join("\n", @goodlines));
 179     my $out = parse_rfc4716body(join('', @goodlines));
 180
 181     return $out;
 182   }
 183
 184   sub parse_rfc4716body {
 185     my $data = shift;
 186
 187     return undef
 188       unless defined($data);
 189     $data = decode_base64($data) or return undef;
 190
 191     msvalog('debug', "key properties: %s\n", unpack('H*', $data));
 192     my $out = [ ];
 193     while (length($data) > 4) {
 194       my $size = unpack('N', substr($data, 0, 4));
 195       msvalog('debug', "size: 0x%08x\n", $size);
 196       return undef if (length($data) < $size + 4);
 197       push(@{$out}, substr($data, 4, $size));
 198       $data = substr($data, 4 + $size);
 199     }
 200
 201     if ($out->[0] ne "ssh-rsa") {
 202       return {error => 'Not an RSA key'};
 203     }
 204
 205     if (scalar(@{$out}) != 3) {
 206       return {error => 'Does not contain the right number of bigints for RSA'};
 207     }
 208
 209     return { exponent => Math::BigInt->from_hex('0x'.unpack('H*', $out->[1])),
 210              modulus => Math::BigInt->from_hex('0x'.unpack('H*', $out->[2])),
 211            } ;
 212   }
 213
 214
 215   # return an arrayref of processes which we can detect that have the
 216   # given socket open (the socket is specified with its inode)
 217   sub getpidswithsocketinode {
 218     my $sockid = shift;
 219
 220     # this appears to be how Linux symlinks open sockets in /proc/*/fd,
 221     # as of at least 2.6.26:
 222     my $socktarget = sprintf('socket:[%d]', $sockid);
 223     my @pids;
 224
 225     my $procfs;
 226     if (opendir($procfs, '/proc')) {
 227       foreach my $pid (grep { /^\d+$/ } readdir($procfs)) {
 228         my $procdir = sprintf('/proc/%d', $pid);
 229         if (-d $procdir) {
 230           my $procfds;
 231           if (opendir($procfds, sprintf('/proc/%d/fd', $pid))) {
 232             foreach my $procfd (grep { /^\d+$/ } readdir($procfds)) {
 233               my $fd = sprintf('/proc/%d/fd/%d', $pid, $procfd);
 234               if (-l $fd) {
 235                 #my ($dev,$ino,$mode,$nlink,$uid,$gid) = lstat($fd);
 236                 my $targ = readlink($fd);
 237                 push @pids, $pid
 238                   if ($targ eq $socktarget);
 239               }
 240             }
 241             closedir($procfds);
 242           }
 243         }
 244       }
 245       closedir($procfs);
 246     }
 247
 248     # FIXME: this whole business is very linux-specific, i think.  i
 249     # wonder how to get this info in other OSes?
 250
 251     return \@pids;
 252   }
 253
 254   # return {uid => X, inode => Y}, meaning the numeric ID of the peer
 255   # on the other end of $socket, "socket inode" identifying the peer's
 256   # open network socket.  each value could be undef if unknown.
 257   sub get_client_info {
 258     my $socket = shift;
 259
 260     my $sock = IO::Socket::->new_from_fd($socket, 'r');
 261     # check SO_PEERCRED -- if this was a TCP socket, Linux
 262     # might not be able to support SO_PEERCRED (even on the loopback),
 263     # though apparently some kernels (Solaris?) are able to.
 264
 265     my $clientid;
 266     my $remotesocketinode;
 267     my $socktype = $sock->sockopt(SO_TYPE) or die "could not get SO_TYPE info";
 268     if (defined $socktype) {
 269       msvalog('debug', "sockopt(SO_TYPE) = %d\n", $socktype);
 270     } else {
 271       msvalog('verbose', "sockopt(SO_TYPE) returned undefined.\n");
 272     }
 273
 274     my $peercred = $sock->sockopt(SO_PEERCRED) or die "could not get SO_PEERCRED info";
 275     my $client = $sock->peername();
 276     my $family = sockaddr_family($client); # should be AF_UNIX (a.k.a. AF_LOCAL) or AF_INET
 277
 278     msvalog('verbose', "socket family: %d\nsocket type: %d\n", $family, $socktype);
 279
 280     if ($peercred) {
 281       # FIXME: on i386 linux, this appears to be three ints, according to
 282       # /usr/include/linux/socket.h.  What about other platforms?
 283       my ($pid, $uid, $gid) = unpack('iii', $peercred);
 284
 285       msvalog('verbose', "SO_PEERCRED: pid: %u, uid: %u, gid: %u\n",
 286               $pid, $uid, $gid,
 287              );
 288       if ($pid != 0 && $uid != 0) { # then we can accept it:
 289         $clientid = $uid;
 290       }
 291       # FIXME: can we get the socket inode as well this way?
 292     }
 293
 294     # another option in Linux would be to parse the contents of
 295     # /proc/net/tcp to find the uid of the peer process based on that
 296     # information.
 297     if (! defined $clientid) {
 298       msvalog('verbose', "SO_PEERCRED failed, digging around in /proc/net/tcp\n");
 299       my $proto;
 300       if ($family == AF_INET) {
 301         $proto = '';
 302       } elsif ($family == AF_INET6) {
 303         $proto = '6';
 304       }
 305       if (defined $proto) {
 306         if ($socktype == &SOCK_STREAM) {
 307           $proto = 'tcp'.$proto;
 308         } elsif ($socktype == &SOCK_DGRAM) {
 309           $proto = 'udp'.$proto;
 310         } else {
 311           undef $proto;
 312         }
 313         if (defined $proto) {
 314           my ($port, $iaddr) = unpack_sockaddr_in($client);
 315           my $iaddrstring = unpack("H*", reverse($iaddr));
 316           msvalog('verbose', "Port: %04x\nAddr: %s\n", $port, $iaddrstring);
 317           my $remmatch = lc(sprintf("%s:%04x", $iaddrstring, $port));
 318           my $infofile = '/proc/net/'.$proto;
 319           my $f = IO::File::->new();
 320           if ( $f->open('< '.$infofile)) {
 321             my @header = split(/ +/, <$f>);
 322             my ($localaddrix, $uidix, $inodeix);
 323             my $ix = 0;
 324             my $skipcount = 0;
 325             while ($ix <= $#header) {
 326               $localaddrix = $ix - $skipcount if (lc($header[$ix]) eq 'local_address');
 327               $uidix = $ix - $skipcount if (lc($header[$ix]) eq 'uid');
 328               $inodeix = $ix - $skipcount if (lc($header[$ix]) eq 'inode');
 329               $skipcount++ if (lc($header[$ix]) eq 'tx_queue') or (lc($header[$ix]) eq 'tr'); # these headers don't actually result in a new column during the data rows
 330               $ix++;
 331             }
 332             if (!defined $localaddrix) {
 333               msvalog('info', "Could not find local_address field in %s; unable to determine peer UID\n",
 334                       $infofile);
 335             } elsif (!defined $uidix) {
 336               msvalog('info', "Could not find uid field in %s; unable to determine peer UID\n",
 337                       $infofile);
 338             } elsif (!defined $inodeix) {
 339               msvalog('info', "Could not find inode field in %s; unable to determine peer network socket inode\n",
 340                       $infofile);
 341             } else {
 342               msvalog('debug', "local_address: %d; uid: %d\n", $localaddrix,$uidix);
 343               while (my @line = split(/ +/,<$f>)) {
 344                 if (lc($line[$localaddrix]) eq $remmatch) {
 345                   if (defined $clientid) {
 346                     msvalog('error', "Warning! found more than one remote uid! (%s and %s\n", $clientid, $line[$uidix]);
 347                   } else {
 348                     $clientid = $line[$uidix];
 349                     $remotesocketinode = $line[$inodeix];
 350                     msvalog('info', "remote peer is uid %d (inode %d)\n",
 351                             $clientid, $remotesocketinode);
 352                   }
 353                 }
 354               }
 355             msvalog('error', "Warning! could not find peer information in %s.  Not verifying.\n", $infofile) unless defined $clientid;
 356             }
 357           } else { # FIXME: we couldn't read the file.  what should we
 358                    # do besides warning?
 359             msvalog('info', "Could not read %s; unable to determine peer UID\n",
 360                     $infofile);
 361           }
 362         }
 363       }
 364     }
 365     return { 'uid' => $clientid,
 366              'inode' => $remotesocketinode };
 367   }
 368
 369   sub handle_request {
 370     my $self = shift;
 371     my $cgi  = shift;
 372
 373     # This is part of a spawned child process.  We don't want the
 374     # child process to destroy the update monitor when it terminates.
 375     $self->{updatemonitor}->forget();
 376     my $clientinfo = get_client_info(select);
 377     my $clientuid = $clientinfo->{uid};
 378
 379     if (defined $clientuid) {
 380       # test that this is an allowed user:
 381       if (exists $self->{allowed_uids}->{$clientuid}) {
 382         msvalog('verbose', "Allowing access from uid %d (%s)\n", $clientuid, $self->{allowed_uids}->{$clientuid});
 383       } else {
 384         msvalog('error', "MSVA client connection from uid %d, forbidden.\n", $clientuid);
 385         printf("HTTP/1.0 403 Forbidden -- peer does not match local user ID\r\nContent-Type: text/plain\r\nDate: %s\r\n\r\nHTTP/1.1 403 Not Found -- peer does not match the local user ID.  Are you sure the agent is running as the same user?\r\n",
 386                strftime("%a, %d %b %Y %H:%M:%S %z", localtime(time())),);
 387         return;
 388       }
 389     }
 390
 391     my $path = $cgi->path_info();
 392     my $handler = $dispatch{$path};
 393
 394     if (ref($handler) eq "HASH") {
 395       if (! exists $handler->{methods}->{$cgi->request_method()}) {
 396         printf("HTTP/1.0 405 Method not allowed\r\nAllow: %s\r\nDate: %s\r\n",
 397                join(', ', keys(%{$handler->{methods}})),
 398                strftime("%a, %d %b %Y %H:%M:%S %z", localtime(time())));
 399       } elsif (ref($handler->{handler}) ne "CODE") {
 400         printf("HTTP/1.0 500 Server Error\r\nDate: %s\r\n",
 401                strftime("%a, %d %b %Y %H:%M:%S %z", localtime(time())));
 402       } else {
 403         my $data = {};
 404         my $ctype = $cgi->content_type();
 405         msvalog('verbose', "Got %s %s (Content-Type: %s)\n", $cgi->request_method(), $path, defined $ctype ? $ctype : '**none supplied**');
 406         if (defined $ctype) {
 407           my @ctypes = split(/; */, $ctype);
 408           $ctype = shift @ctypes;
 409           if ($ctype eq 'application/json') {
 410             $data = from_json($cgi->param('POSTDATA'));
 411           }
 412         };
 413
 414         my ($status, $object) = $handler->{handler}($data, $clientinfo);
 415         if (ref($object) eq 'HASH' &&
 416             ! defined $object->{server}) {
 417           $object->{server} = sprintf("MSVA-Perl %s", $VERSION);
 418         }
 419
 420         my $ret = to_json($object);
 421         msvalog('info', "returning: %s\n", $ret);
 422         printf("HTTP/1.0 %s\r\nDate: %s\r\nContent-Type: application/json\r\n\r\n%s",
 423                $status,
 424                strftime("%a, %d %b %Y %H:%M:%S %z", localtime(time())),
 425                $ret);
 426       }
 427     } else {
 428       printf("HTTP/1.0 404 Not Found -- not handled by Monkeysphere validation agent\r\nContent-Type: text/plain\r\nDate: %s\r\n\r\nHTTP/1.0 404 Not Found -- the path:\r\n   %s\r\nis not handled by the MonkeySphere validation agent.\r\nPlease try one of the following paths instead:\r\n\r\n%s\r\n",
 429              strftime("%a, %d %b %Y %H:%M:%S %z", localtime(time())),
 430              $path, ' * '.join("\r\n * ", keys %dispatch) );
 431     }
 432   }
 433
 434   sub keycomp {
 435     my $rsakey = shift;
 436     my $gpgkey = shift;
 437
 438     if ($gpgkey->algo_num != 1) {
 439       msvalog('verbose', "Monkeysphere only does RSA keys.  This key is algorithm #%d\n", $gpgkey->algo_num);
 440     } else {
 441       if ($rsakey->{exponent}->bcmp($gpgkey->pubkey_data->[1]) == 0 &&
 442           $rsakey->{modulus}->bcmp($gpgkey->pubkey_data->[0]) == 0) {
 443         return 1;
 444       }
 445     }
 446     return 0;
 447   }
 448
 449   sub pem2der {
 450     my $pem = shift;
 451     my @lines = split(/\n/, $pem);
 452     my @goodlines = ();
 453     my $ready = 0;
 454     foreach my $line (@lines) {
 455       if ($line eq '-----END CERTIFICATE-----') {
 456         last;
 457       } elsif ($ready) {
 458         push @goodlines, $line;
 459       } elsif ($line eq '-----BEGIN CERTIFICATE-----') {
 460         $ready = 1;
 461       }
 462     }
 463     msvalog('debug', "%d lines of base64:\n%s\n", $#goodlines + 1, join("\n", @goodlines));
 464     return decode_base64(join('', @goodlines));
 465   }
 466
 467   sub der2key {
 468     my $rawdata = shift;
 469
 470     my $cert = Crypt::X509::->new(cert => $rawdata);
 471
 472     my $key = {error => 'I do not know what happened here'};
 473
 474     if ($cert->error) {
 475       $key->{error} = sprintf("Error decoding X.509 certificate: %s", $cert->error);
 476     } else {
 477       msvalog('verbose', "cert subject: %s\n", $cert->subject_cn());
 478       msvalog('verbose', "cert issuer: %s\n", $cert->issuer_cn());
 479       msvalog('verbose', "cert pubkey algo: %s\n", $cert->PubKeyAlg());
 480       msvalog('verbose', "cert pubkey: %s\n", unpack('H*', $cert->pubkey()));
 481
 482       if ($cert->PubKeyAlg() ne 'RSA') {
 483         $key->{error} = sprintf('public key was algo "%s" (OID %s).  MSVA.pl only supports RSA',
 484                                 $cert->PubKeyAlg(), $cert->pubkey_algorithm);
 485       } else {
 486         msvalog('debug', "decoding ASN.1 pubkey\n");
 487         $key = $rsa_decoder->decode($cert->pubkey());
 488         if (! defined $key) {
 489           msvalog('verbose', "failed to decode %s\n", unpack('H*', $cert->pubkey()));
 490           $key = {error => 'failed to decode the public key'};
 491         }
 492       }
 493     }
 494     return $key;
 495   }
 496
 497   sub get_keyserver_policy {
 498     if (exists $ENV{MSVA_KEYSERVER_POLICY} and $ENV{MSVA_KEYSERVER_POLICY} ne '') {
 499       if ($ENV{MSVA_KEYSERVER_POLICY} =~ /^(always|never|unlessvalid)$/) {
 500         return $1;
 501       }
 502       msvalog('error', "Not a valid MSVA_KEYSERVER_POLICY):\n  %s\n", $ENV{MSVA_KEYSERVER_POLICY});
 503     }
 504     return $default_keyserver_policy;
 505   }
 506
 507   sub get_keyserver {
 508     # We should read from (first hit wins):
 509     # the environment
 510     if (exists $ENV{MSVA_KEYSERVER} and $ENV{MSVA_KEYSERVER} ne '') {
 511       if ($ENV{MSVA_KEYSERVER} =~ /^(((hkps?|hkpms|finger|ldap):\/\/)?$RE{net}{domain})$/) {
 512         return $1;
 513       }
 514       msvalog('error', "Not a valid keyserver (from MSVA_KEYSERVER):\n  %s\n", $ENV{MSVA_KEYSERVER});
 515     }
 516
 517     # FIXME: some msva.conf or monkeysphere.conf file (system and user?)
 518
 519     # or else read from the relevant gnupg.conf:
 520     my $gpghome;
 521     if (exists $ENV{GNUPGHOME} and $ENV{GNUPGHOME} ne '') {
 522       $gpghome = untaint($ENV{GNUPGHOME});
 523     } else {
 524       $gpghome = File::Spec->catfile(File::HomeDir->my_home, '.gnupg');
 525     }
 526     my $gpgconf = File::Spec->catfile($gpghome, 'gpg.conf');
 527     if (-f $gpgconf) {
 528       if (-r $gpgconf) {
 529         my %gpgconfig = Config::General::ParseConfig($gpgconf);
 530         if ($gpgconfig{keyserver} =~ /^(((hkps?|hkpms|finger|ldap):\/\/)?$RE{net}{domain})$/) {
 531           msvalog('debug', "Using keyserver %s from the GnuPG configuration file (%s)\n", $1, $gpgconf);
 532           return $1;
 533         } else {
 534           msvalog('error', "Not a valid keyserver (from gpg config %s):\n  %s\n", $gpgconf, $gpgconfig{keyserver});
 535         }
 536       } else {
 537         msvalog('error', "The GnuPG configuration file (%s) is not readable\n", $gpgconf);
 538       }
 539     } else {
 540       msvalog('info', "Did not find GnuPG configuration file while looking for keyserver '%s'\n", $gpgconf);
 541     }
 542
 543     # the default_keyserver
 544     return $default_keyserver;
 545   }
 546
 547   sub fetch_uid_from_keyserver {
 548     my $uid = shift;
 549
 550     my $cmd = IO::Handle::->new();
 551     my $out = IO::Handle::->new();
 552     my $nul = IO::File::->new("< /dev/null");
 553
 554     my $ks = get_keyserver();
 555     msvalog('debug', "start ks query to %s for UserID: %s\n", $ks, $uid);
 556     my $pid = $gnupg->wrap_call
 557       ( handles => GnuPG::Handles::->new( command => $cmd, stdout => $out, stderr => $nul ),
 558         command_args => [ '='.$uid ],
 559         commands => [ '--keyserver',
 560                       $ks,
 561                       qw( --no-tty --with-colons --search ) ]
 562       );
 563     while (my $line = $out->getline()) {
 564       msvalog('debug', "from ks query: (%d) %s", $cmd->fileno, $line);
 565       if ($line =~ /^info:(\d+):(\d+)/ ) {
 566         $cmd->print(join(' ', ($1..$2))."\n");
 567         msvalog('debug', 'to ks query: '.join(' ', ($1..$2))."\n");
 568         last;
 569       }
 570     }
 571     # FIXME: can we do something to avoid hanging forever?
 572     waitpid($pid, 0);
 573     msvalog('debug', "ks query returns %d\n", POSIX::WEXITSTATUS($?));
 574   }
 575
 576   sub reviewcert {
 577     my $data  = shift;
 578     my $clientinfo  = shift;
 579     return if !ref $data;
 580
 581     msvalog('verbose', "reviewing data...\n");
 582
 583     my $status = '200 OK';
 584     my $ret =  { valid => JSON::false,
 585                  message => 'Unknown failure',
 586                };
 587
 588     # check context string
 589     if ($data->{context} =~ /^(https|ssh|smtp|ike|postgresql|imaps|imap|submission)$/) {
 590         $data->{context} = $1;
 591     } else {
 592         msvalog('error', "invalid context: %s\n", $data->{context});
 593         $ret->{message} = sprintf("Invalid/unknown context: %s", $data->{context});
 594         return $status,$ret;
 595     }
 596     msvalog('verbose', "context: %s\n", $data->{context});
 597
 598     # checkout peer string
 599     # old-style just passed a string as a peer, rather than
 600     # peer: { name: 'whatever', 'type': 'client' }
 601     $data->{peer} = { name => $data->{peer} }
 602       if (ref($data->{peer}) ne 'HASH');
 603
 604     if (defined($data->{peer}->{type})) {
 605       if ($data->{peer}->{type} =~ /^(client|server|peer)$/) {
 606         $data->{peer}->{type} = $1;
 607       } else {
 608         msvalog('error', "invalid peer type string: %s\n", $data->{peer}->{type});
 609         $ret->{message} = sprintf("Invalid peer type string: %s", $data->{peer}->{type});
 610         return $status,$ret;
 611       }
 612     }
 613
 614     my $prefix = $data->{context}.'://';
 615     if (defined $data->{peer}->{type} &&
 616         $data->{peer}->{type} eq 'client' &&
 617         # ike and smtp clients are effectively other servers, so we'll
 618         # exclude them:
 619         $data->{context} !~ /^(ike|smtp)$/) {
 620       $prefix = '';
 621       # clients can have any one-line User ID without NULL characters
 622       # and leading or trailing whitespace
 623       if ($data->{peer}->{name} =~ /^([^[:space:]][^\n\0]*[^[:space:]]|[^\0[:space:]])$/) {
 624         $data->{peer}->{name} = $1;
 625       } else {
 626         msvalog('error', "invalid client peer name string: %s\n", $data->{peer}->{name});
 627         $ret->{message} = sprintf("Invalid client peer name string: %s", $data->{peer}->{name});
 628         return $status, $ret;
 629       }
 630     } elsif ($data->{peer}->{name} =~ /^($RE{net}{domain}(:[[:digit:]]+)?)$/) {
 631       $data->{peer}->{name} = $1;
 632     } else {
 633       msvalog('error', "invalid peer name string: %s\n", $data->{peer}->{name});
 634       $ret->{message} = sprintf("Invalid peer name string: %s", $data->{peer}->{name});
 635       return $status,$ret;
 636     }
 637
 638     msvalog('verbose', "peer: %s\n", $data->{peer}->{name});
 639
 640     # generate uid string
 641     my $uid = $prefix.$data->{peer}->{name};
 642     msvalog('verbose', "user ID: %s\n", $uid);
 643
 644     # check pkc type
 645     my $key;
 646     if (lc($data->{pkc}->{type}) eq 'x509der') {
 647       $key = der2key(join('', map(chr, @{$data->{pkc}->{data}})));
 648     } elsif (lc($data->{pkc}->{type}) eq 'x509pem') {
 649       $key = der2key(pem2der($data->{pkc}->{data}));
 650     } elsif (lc($data->{pkc}->{type}) eq 'opensshpubkey') {
 651       $key = opensshpubkey2key($data->{pkc}->{data});
 652     } elsif (lc($data->{pkc}->{type}) eq 'rfc4716') {
 653       $key = rfc47162key($data->{pkc}->{data});
 654     } else {
 655       $ret->{message} = sprintf("Don't know this public key carrier type: %s", $data->{pkc}->{type});
 656       return $status,$ret;
 657     }
 658
 659     if (exists $key->{error}) {
 660       $ret->{message} = $key->{error};
 661       return $status,$ret;
 662     }
 663
 664     # make sure that the returned integers are Math::BigInts:
 665     $key->{exponent} = Math::BigInt::->new($key->{exponent}) unless (ref($key->{exponent}));
 666     $key->{modulus} = Math::BigInt::->new($key->{modulus}) unless (ref($key->{modulus}));
 667     msvalog('debug', "pubkey info:\nmodulus: %s\nexponent: %s\n",
 668             $key->{modulus}->as_hex(),
 669             $key->{exponent}->as_hex(),
 670            );
 671
 672     if ($key->{modulus}->copy()->blog(2) < 1000) {
 673       $ret->{message} = sprintf('Public key size is less than 1000 bits (was: %d bits)', $key->{modulus}->copy()->blog(2));
 674     } else {
 675       $ret->{message} = sprintf('Failed to validate "%s" through the OpenPGP Web of Trust.', $uid);
 676       my $lastloop = 0;
 677       my $kspolicy;
 678       if (defined $data->{keyserverpolicy} &&
 679           $data->{keyserverpolicy} =~ /^(always|never|unlessvalid)$/) {
 680         $kspolicy = $1;
 681         msvalog("verbose", "using requested keyserver policy: %s\n", $1);
 682       } else {
 683         $kspolicy = get_keyserver_policy();
 684       }
 685       msvalog('debug', "keyserver policy: %s\n", $kspolicy);
 686       # needed because $gnupg spawns child processes
 687       $ENV{PATH} = '/usr/local/bin:/usr/bin:/bin';
 688       if ($kspolicy eq 'always') {
 689         fetch_uid_from_keyserver($uid);
 690         $lastloop = 1;
 691       } elsif ($kspolicy eq 'never') {
 692         $lastloop = 1;
 693       }
 694       my $foundvalid = 0;
 695
 696       # fingerprints of keys that are not fully-valid for this User ID, but match
 697       # the key from the queried certificate:
 698       my @subvalid_key_fprs;
 699
 700       while (1) {
 701         foreach my $gpgkey ($gnupg->get_public_keys('='.$uid)) {
 702           my $validity = '-';
 703           foreach my $tryuid ($gpgkey->user_ids) {
 704             if ($tryuid->as_string eq $uid) {
 705               $validity = $tryuid->validity;
 706             }
 707           }
 708           # treat primary keys just like subkeys:
 709           foreach my $subkey ($gpgkey, @{$gpgkey->subkeys}) {
 710             my $primarymatch = keycomp($key, $subkey);
 711             if ($primarymatch) {
 712               if ($subkey->usage_flags =~ /a/) {
 713                 msvalog('verbose', "key matches, and 0x%s is authentication-capable\n", $subkey->hex_id);
 714                 if ($validity =~ /^[fu]$/) {
 715                   $foundvalid = 1;
 716                   msvalog('verbose', "...and it matches!\n");
 717                   $ret->{valid} = JSON::true;
 718                   $ret->{message} = sprintf('Successfully validated "%s" through the OpenPGP Web of Trust.', $uid);
 719                 } else {
 720                   push(@subvalid_key_fprs, { fpr => $subkey->fingerprint, val => $validity }) if $lastloop;
 721                 }
 722               } else {
 723                 msvalog('verbose', "key matches, but 0x%s is not authentication-capable\n", $subkey->hex_id);
 724               }
 725             }
 726           }
 727         }
 728         if ($lastloop) {
 729           last;
 730         } else {
 731           fetch_uid_from_keyserver($uid) if (!$foundvalid);
 732           $lastloop = 1;
 733         }
 734       }
 735
 736       # only show the marginal UI if the UID of the corresponding
 737       # key is not fully valid.
 738       if (!$foundvalid) {
 739         my $resp = Crypt::Monkeysphere::MSVA::MarginalUI->ask_the_user($gnupg,
 740                                                                        $uid,
 741                                                                        \@subvalid_key_fprs,
 742                                                                        getpidswithsocketinode($clientinfo->{inode}),
 743                                                                        $logger);
 744         msvalog('info', "response: %s\n", $resp);
 745         if ($resp) {
 746           $ret->{valid} = JSON::true;
 747           $ret->{message} = sprintf('Manually validated "%s" through the OpenPGP Web of Trust.', $uid);
 748         }
 749       }
 750     }
 751     return $status, $ret;
 752   }
 753
 754   sub pre_loop_hook {
 755     my $self = shift;
 756     my $server = shift;
 757
 758     $self->spawn_master_subproc($server);
 759   }
 760
 761   sub master_subprocess_died {
 762     my $self = shift;
 763     my $server = shift;
 764     my $subproc_return = shift;
 765
 766     my $exitstatus = POSIX::WEXITSTATUS($subproc_return);
 767     msvalog('verbose', "Subprocess %d terminated; exiting %d.\n", $self->{child_pid}, $exitstatus);
 768     $server->set_exit_status($exitstatus);
 769     $server->server_close();
 770   }
 771
 772   sub child_dies {
 773     my $self = shift;
 774     my $pid = shift;
 775     my $server = shift;
 776
 777     msvalog('debug', "Subprocess %d terminated.\n", $pid);
 778
 779     if (exists $self->{updatemonitor} &&
 780         defined $self->{updatemonitor}->getchildpid() &&
 781         $self->{updatemonitor}->getchildpid() == $pid) {
 782       my $exitstatus = POSIX::WEXITSTATUS($?);
 783       msvalog('verbose', "Update monitoring process (%d) terminated with code %d.\n", $pid, $exitstatus);
 784       if (0 == $exitstatus) {
 785         msvalog('info', "Reloading MSVA due to update request.\n");
 786         # sending self a SIGHUP:
 787         kill(1, $$);
 788       } else {
 789         msvalog('error', "Update monitoring process (%d) died unexpectedly with code %d.\nNo longer monitoring for updates; please send HUP manually.\n", $pid, $exitstatus);
 790         # it died for some other weird reason; should we respawn it?
 791
 792         # FIXME: i'm worried that re-spawning would create a
 793         # potentially abusive loop, if there are legit, repeatable
 794         # reasons for the failure.
 795
 796 #        $self->{updatemonitor}->spawn();
 797
 798         # instead, we'll just avoid trying to kill the next process with this PID:
 799         $self->{updatemonitor}->forget();
 800       }
 801     } elsif (exists $self->{child_pid} &&
 802              ($self->{child_pid} == 0 ||
 803               $self->{child_pid} == $pid)) {
 804       $self->master_subprocess_died($server, $?);
 805     }
 806   }
 807
 808   # use sparingly!  We want to keep taint mode around for the data we
 809   # get over the network.  this is only here because we want to treat
 810   # the command line arguments differently for the subprocess.
 811   sub untaint {
 812     my $x = shift;
 813     $x =~ /^(.*)$/ ;
 814     return $1;
 815   }
 816
 817   sub post_bind_hook {
 818     my $self = shift;
 819     my $server = shift;
 820
 821     $server->{server}->{leave_children_open_on_hup} = 1;
 822
 823     my $socketcount = @{ $server->{server}->{sock} };
 824     if ( $socketcount != 1 ) {
 825       msvalog('error', "%d sockets open; should have been 1.\n", $socketcount);
 826       $server->set_exit_status(10);
 827       $server->server_close();
 828     }
 829     my $port = @{ $server->{server}->{sock} }[0]->sockport();
 830     if ((! defined $port) || ($port < 1) || ($port >= 65536)) {
 831       msvalog('error', "got nonsense port: %d.\n", $port);
 832       $server->set_exit_status(11);
 833       $server->server_close();
 834     }
 835     if ((exists $ENV{MSVA_PORT}) && (($ENV{MSVA_PORT} + 0) != $port)) {
 836       msvalog('error', "Explicitly requested port %d, but got port: %d.", ($ENV{MSVA_PORT}+0), $port);
 837       $server->set_exit_status(13);
 838       $server->server_close();
 839     }
 840     $self->port($port);
 841     $self->{updatemonitor} = Crypt::Monkeysphere::MSVA::Monitor::->new($logger);
 842   }
 843
 844   sub spawn_master_subproc {
 845     my $self = shift;
 846     my $server = shift;
 847
 848     if ((exists $ENV{MSVA_CHILD_PID}) && ($ENV{MSVA_CHILD_PID} ne '')) {
 849       # this is most likely a re-exec.
 850       msvalog('info', "This appears to be a re-exec, continuing with child pid %d\n", $ENV{MSVA_CHILD_PID});
 851       $self->{child_pid} = $ENV{MSVA_CHILD_PID} + 0;
 852     } elsif ($#ARGV >= 0) {
 853       $self->{child_pid} = 0; # indicate that we are planning to fork.
 854       # avoid ignoring SIGCHLD right before we fork.
 855       $SIG{CHLD} = sub {
 856         my $val;
 857         while (defined($val = POSIX::waitpid(-1, POSIX::WNOHANG)) && $val > 0) {
 858           $self->child_dies($val, $server);
 859         }
 860       };
 861       my $fork = fork();
 862       if (! defined $fork) {
 863         msvalog('error', "could not fork\n");
 864       } else {
 865         if ($fork) {
 866           msvalog('debug', "Child process has PID %d\n", $fork);
 867           $self->{child_pid} = $fork;
 868           $ENV{MSVA_CHILD_PID} = $fork;
 869         } else {
 870           msvalog('verbose', "PID %d executing: \n", $$);
 871           for my $arg (@ARGV) {
 872             msvalog('verbose', " %s\n", $arg);
 873           }
 874           # untaint the environment for the subprocess
 875           # see: https://labs.riseup.net/code/issues/2461
 876           foreach my $e (keys %ENV) {
 877             $ENV{$e} = untaint($ENV{$e});
 878           }
 879           my @args;
 880           foreach (@ARGV) {
 881             push @args, untaint($_);
 882           }
 883           # restore default SIGCHLD handling:
 884           $SIG{CHLD} = 'DEFAULT';
 885           $ENV{MONKEYSPHERE_VALIDATION_AGENT_SOCKET} = sprintf('http://localhost:%d', $self->port);
 886           exec(@args) or exit 111;
 887         }
 888       }
 889     } else {
 890       printf("MONKEYSPHERE_VALIDATION_AGENT_SOCKET=http://localhost:%d;\nexport MONKEYSPHERE_VALIDATION_AGENT_SOCKET;\n", $self->port);
 891       # FIXME: consider daemonizing here to behave more like
 892       # ssh-agent.  maybe avoid backgrounding by setting
 893       # MSVA_NO_BACKGROUND.
 894     };
 895   }
 896
 897   sub extracerts {
 898     my $data = shift;
 899
 900     return '500 not yet implemented', { };
 901   }
 902
 903   1;
 904 }